TITLE:
Ch 11a: Constant-Centered Student Vicitimization Predicting Student Closeness
For Table 11.3: Level-2 and Level-3 Effects, Omitting Level-1 Effect
DATA:
FILE = MPLUS_Chapter11a.csv;
FORMAT = FREE;
VARIABLE:
NAMES = ClassID grade size StudID girl SMclose SMvic CMclose CMvic CMg CMemo
size23 grade35 CMg50 CMemo5 CMvic3 WCclose SMvic3 WCvic wave emo vic close
time1 time2 w3 WSclose vic3 WSvic emo5 WCemo;
USEVARIABLES = close time1 girl CMg50 CMemo5 SMvic3 CMvic3;
MISSING = ALL (-9999);
CLUSTER = ClassID StudID;
WITHIN = time1;
BETWEEN = (StudID) girl SMvic3 (ClassID) CMg50 CMemo5 CMvic3;
ANALYSIS:
ESTIMATOR = ML;
PROCESSORS = 4;
TYPE = THREELEVEL RANDOM;
MODEL:
%WITHIN%
close;
lin | close ON time1;
%BETWEEN StudID%
close lin;
close WITH lin;
close lin ON girl (bintL2g blinL2g);
intL2v | close ON SMvic3;
%BETWEEN ClassID%
[close lin intL2v] (int btime1 bintL2v);
close lin intL2v@0;
close WITH lin;
close lin ON CMg50 (bintL3g blinL3g);
close lin ON CMemo5 (bintL3e blinL3e);
close ON CMvic3 (bintL3v);