TITLE:
  Ch 4: Empty Means, n-1 Lag Toeplitz Heterogeneous R-Only Model

DATA:
  FILE = MPLUS_Chapter4.csv;
  FORMAT = FREE;

DATA LONGTOWIDE:
  LONG = posmood;
  WIDE = posmood1-posmood7;
  IDVARIABLE = PersonID;
  REPETITION = studyday (1-7);

VARIABLE:
  NAMES = PersonID studyday posmood;
  USEVARIABLES = posmood1-posmood7;
  MISSING = ALL (-9999);

ANALYSIS:
  ESTIMATOR = ML;
  PROCESSORS = 4;

OUTPUT:
  STDYX;

MODEL:
  posmood1-posmood7 (totvar1-totvar7);
  posmood1-posmood6 PWITH posmood2-posmood7 (totcov1-totcov6);
  posmood1-posmood5 PWITH posmood3-posmood7 (totcov7-totcov11);
  posmood1-posmood4 PWITH posmood4-posmood7 (totcov12-totcov15);
  posmood1-posmood3 PWITH posmood5-posmood7 (totcov16-totcov18);
  posmood1-posmood2 PWITH posmood6-posmood7 (totcov19-totcov20);
  posmood1          PWITH posmood7          (totcov21);
  [posmood1-posmood7] (mean);

MODEL CONSTRAINT:
  NEW(TOEPcor1 TOEPcor2 TOEPcor3 TOEPcor4 TOEPcor5 TOEPcor6);
! Total Covariance for Studyday 1 and 2
  totcov1  = TOEPcor1*SQRT(totvar1)*SQRT(totvar2);
! Total Covariance for Studyday 2 and 3
  totcov2  = TOEPcor1*SQRT(totvar2)*SQRT(totvar3);
! Total Covariance for Studyday 3 and 4
  totcov3  = TOEPcor1*SQRT(totvar3)*SQRT(totvar4);
! Total Covariance for Studyday 4 and 5
  totcov4  = TOEPcor1*SQRT(totvar4)*SQRT(totvar5);
! Total Covariance for Studyday 5 and 6
  totcov5  = TOEPcor1*SQRT(totvar5)*SQRT(totvar6);
! Total Covariance for Studyday 6 and 7
  totcov6  = TOEPcor1*SQRT(totvar6)*SQRT(totvar7);
! Total Covariance for Studyday 1 and 3
  totcov7  = TOEPcor2*SQRT(totvar1)*SQRT(totvar3);
! Total Covariance for Studyday 2 and 4
  totcov8  = TOEPcor2*SQRT(totvar2)*SQRT(totvar4);
! Total Covariance for Studyday 3 and 5
  totcov9  = TOEPcor2*SQRT(totvar3)*SQRT(totvar5);
! Total Covariance for Studyday 4 and 6
  totcov10 = TOEPcor2*SQRT(totvar4)*SQRT(totvar6);
! Total Covariance for Studyday 5 and 7
  totcov11 = TOEPcor2*SQRT(totvar5)*SQRT(totvar7);
! Total Covariance for Studyday 1 and 4
  totcov12 = TOEPcor3*SQRT(totvar1)*SQRT(totvar4);
! Total Covariance for Studyday 2 and 5
  totcov13 = TOEPcor3*SQRT(totvar2)*SQRT(totvar5);
! Total Covariance for Studyday 3 and 6
  totcov14 = TOEPcor3*SQRT(totvar3)*SQRT(totvar6);
! Total Covariance for Studyday 4 and 7
  totcov15 = TOEPcor3*SQRT(totvar4)*SQRT(totvar7);
! Total Covariance for Studyday 1 and 5
  totcov16 = TOEPcor4*SQRT(totvar1)*SQRT(totvar5);
! Total Covariance for Studyday 2 and 6
  totcov17 = TOEPcor4*SQRT(totvar2)*SQRT(totvar6);
! Total Covariance for Studyday 3 and 7
  totcov18 = TOEPcor4*SQRT(totvar3)*SQRT(totvar7);
! Total Covariance for Studyday 1 and 6
  totcov19 = TOEPcor5*SQRT(totvar1)*SQRT(totvar6);
! Total Covariance for Studyday 2 and 7
  totcov20 = TOEPcor5*SQRT(totvar2)*SQRT(totvar7);
! Total Covariance for Studyday 1 and 7
  totcov21 = TOEPcor6*SQRT(totvar1)*SQRT(totvar7);