TITLE:
  Eq 8.7: Adding a Contextual Effect of Negative Mood to the Model for the Means
  Using Person-Mean-Centering for Negative Mood

DATA:
  ! Prior necessary data manipulation conducted using other programs
  FILE = MPLUS_Chapter8.csv;
  FORMAT = FREE;

DEFINE:
  sexage = women*age80;

VARIABLE:
  NAMES = PersonID women baseage session studyday dayweek weekend symp mood stress
          PMmood PMstr age80 mood2 WPmood PMmood2 WPstr PMstr40;
  USEVARIABLES = symp women age80 PMmood2 mood2 sexage;
  MISSING = ALL (-9999);
  CLUSTER = PersonID;
  WITHIN = mood2;
  BETWEEN = women age80 PMmood2 sexage;

ANALYSIS:
  ESTIMATOR = ML;
  PROCESSORS = 4;
  TYPE = TWOLEVEL RANDOM;

MODEL:

%WITHIN%
  symp;
  L1mood | symp ON mood2;

%BETWEEN%
  [symp L1mood] (int bmood2);
  symp L1mood@0;
  symp ON women age80 sexage (bwomen bage80 bsexage);
  symp ON PMmood2 (bPMmood2);

MODEL CONSTRAINT:
  NEW(est1-est3);
! est1: Age Slope for Men
  est1 = bage80*1 + bsexage*0;
! est2: Age Slope for Women
  est2 = bage80*1 + bsexage*1;
! est3: Between-Person Negative Mood Effect
  est3 = bmood2*1 + bPMmood2*1;